Hi,
Yes, this is fully supported.
As a starting point, we always recommend to use APIMate. Create the file you want in Excel, then open it with ApiMate (start menu->tms flexcel->tools)and look at the code.
As an example, I tried with a file with an image here, and I got:
//Images
fs := TFileStream.Create('imagename.png', fmOpenRead or fmShareDenyNone);
try
ImgProps := TImageProperties_Create();
ImgProps.Anchor := TClientAnchor.Create(TFlxAnchorType.MoveAndDontResize, 2, 0, 2, 0, 5, 204, 9, 416);
ImgProps.ShapeName := 'Picture 1';
xls.AddImage(fs, ImgProps);
finally
fs.Free;
end;
This would add an image from row 2, column 2, to row 5, column 9.
And well, once we have this, we need to get deeper in how to specify the coordinates of the image.
In Excel, images are always saved with their position and size relative to cells.
So for example, you might have an image going form row 1, col 3, to row 7, col 8. And then you specify the offset from the start of the cell. For example, the image might go from row 1, with an offset of 128, and that would mean it starts at the middle of row 1. (offsets go from 0 to 255 in rows, and 0 to 1024 in columns, so a row offset of 255 would mean the next row).
And well, APIMate shows you the TClientAnchor constructor that specifies starting and ending (row, col) and their offsets:
TClientAnchor.Create(TFlxAnchorType.MoveAndDontResize, 2, 0, 2, 0, 5, 204, 9, 416);
But you normally don't really know the end row,col, as this depends on the image, aspect ratio and column/row sizes.
So we have an overload that you might use instead of what APIMate suggests:
/// <summary>
/// Creates a new image based on the image size.
/// </summary>
/// <param name="aAnchorType">How the image behaves when copying/inserting cells.</param>
/// <param name="aRow1">Row where to insert the image.</param>
/// <param name="aCol1">Column where to insert the image.</param>
/// <param name="aPixDy1">Delta in pixels that the image is moved from aRow1.</param>
/// <param name="aPixDx1">Delta in pixels that the image is moved from aCol1.</param>
/// <param name="height">Height in pixels.</param>
/// <param name="width">Width in pixels.</param>
/// <param name="Workbook">ExcelFile with the workbook, used to calculate the cells.</param>
class function Create(const aAnchorType: TFlxAnchorType; const aRow1: Int32; const aPixDy1: Int32; const aCol1: Int32; const aPixDx1: Int32; const height: Int32; const width: Int32; const Workbook: IRowColSize): TClientAnchor; overload; static;
With this overload, you specify the height and width of the image, in "pixels". But note that "pixel" here is a loose term, because while images are measured in pixels, Excel uses inches. For example, if your monitor has 96 dots per inch, then an image with 96 pixels would be 1inch. But when you print it in a 600 dpi printer, it would be 96/600 inches. And in a high res monitor, it would be another size. So Excel will always consider the absolute (inches) size of the image, and resize it so it looks the same.
When you specify a height and width in pixels for the anchor, FlexCel will use 96dpi to calculate the ending row, col and offsets that it needs to write in the xls/x files.
You don't need to be so exact with the pixel dimensions, it doesn't really matter as the image will most likely be resized anyway, depending in the monitor resolution. But you need to keep the aspect ratio.
You might already know the pixel dimensions of the image, or you might use a TPicture object to get them, or a FlexCel's TUIImage object.
And once you create the anchor using the width and height, you can get the end (row, col) of the anchor, so you can fill the data after that.
Here is a little code snippet that would do all the stuff described. It will open an image to see its dimensions, then insert it at row 2, col 3, and then write "Hello from FlexCel" at the row completely below the image, and column completely to the right of the image
procedure CreateFile;
var
xls: TExcelFile;
fs: TFileStream;
ImgProps: IImageProperties;
img: TUIImage;
begin
xls := TXlsFile.Create(true);
xls.NewFile(1, TExcelFileFormat.v2010); //Create a new Excel file with 3 sheets.
//Set the names of the sheets
xls.ActiveSheet := 1;
//Images
fs := TFileStream.Create('r:\test.png', fmOpenRead or fmShareDenyNone);
try
img := TUIImage.FromStream(fs);
try
ImgProps := TImageProperties_Create();
ImgProps.Anchor := TClientAnchor.Create(TFlxAnchorType.MoveAndDontResize,
2, 0, 3, 0, Trunc(img.Height), Trunc(img.Width), xls);
ImgProps.ShapeName := 'Picture 1';
finally
img.Free;
end;
fs.Position := 0;
xls.AddImage(fs, ImgProps);
finally
fs.Free;
end;
xls.SetCellValue(ImgProps.Anchor.Row2 + 1, ImgProps.Anchor.Col2 + 1, 'Hello from FlexCel');
xls.Save('r:\test.xlsx');
end;